<%
'#################################################################################
'## Copyright (C) 2000-01 Michael Anderson and Pierre Gorissen
'## 
'## This program is free software; you can redistribute it and/or
'## modify it under the terms of the GNU General Public License
'## as published by the Free Software Foundation; either version 2
'## of the License, or any later version.
'##
'## All copyright notices regarding Snitz Forums 2000
'## must remain intact in the scripts and in the outputted HTML
'## The "powered by" text/logo with a link back to 
'## http://forum.snitz.com in the footer of the pages MUST
'## remain visible when the pages are viewed on the internet or intranet.
'## 
'## This program is distributed in the hope that it will be useful,
'## but WITHOUT ANY WARRANTY; without even the implied warranty of
'## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
'## GNU General Public License for more details.
'## 
'## You should have received a copy of the GNU General Public License
'## along with this program; if not, write to the Free Software
'## Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA  02111-1307, USA.
'## 
'## Support can be obtained from support forums at:
'## http://forum.snitz.com 
'##
'## Correspondence and Marketing Questions can be sent to:
'## reinhold@bigfoot.com
'## 
'## or
'## 
'## Snitz Communications 
'## C/O: Michael Anderson
'## PO Box 200
'## Harpswell, ME 04079
'#################################################################################

'#################################################################################
'## Variable declaration 
'#################################################################################
dim strSelecSize
dim intCols, intRows
%>
<!--#INCLUDE FILE="config.asp" --> 
<!--#INCLUDE FILE="inc_functions.asp" -->
<!--#INCLUDE FILE="inc_code.asp" -->
<%
'#################################################################################
'## Initialise variables 
'#################################################################################
strSelectSize = Request.Form("SelectSize") 
strRqMethod = Request.QueryString("method")
strRqTopicID = Request.QueryString("TOPIC_ID")
strRqForumID = Request.QueryString("FORUM_ID")
strRqCatID = Request.QueryString("CAT_ID")
strCkPassWord = Request.Cookies(strUniqueID & "User")("Pword")
'#################################################################################
'## Page-code start
'#################################################################################

if request("ARCHIVE") = "true" then
	strActivePrefix = strTablePrefix & "A_"
	ArchiveView = "true"
else
	strActivePrefix = strTablePrefix
	ArchiveView = ""
end if

if strSelectSize = "" or IsNull(strSelectSize) then 
	strSelectSize = Request.Cookies(strCookieURL & "strSelectSize")
end if
if not(IsNull(strSelectSize)) then 
	Response.Cookies(strCookieURL & "strSelectSize") = strSelectSize
	Response.Cookies(strCookieURL & "strSelectSize").expires = Now() + 365
end if
%>
<!--#INCLUDE FILE="inc_top.asp" -->
<%

if ArchiveView <> "" then
	if MethodType = "Reply" or _
	MethodType = "ReplyQuote" or _
	MethodType = "TopicQuote" then

		Go_Result "This is not allowed in the Archives."

	end if
end if


if strRqMethod = "Edit" or _
strRqMethod = "EditTopic" or _
strRqMethod = "Reply" or _
strRqMethod = "ReplyQuote" or _
strRqMethod = "Topic" or _
strRqMethod = "TopicQuote" then
 
	if strRqMethod <> "Topic" then
		'## Forum_SQL - Find out if the Category, Forum or Topic is Locked or Un-Locked and if it Exists
		strSql = "SELECT " & strTablePrefix & "CATEGORY.CAT_STATUS, " &_
		strTablePrefix & "FORUM.F_STATUS, " &_
		strActivePrefix & "TOPICS.T_STATUS " &_
		" FROM " & strTablePrefix & "CATEGORY, " &_
		strTablePrefix & "FORUM, " &_
		strActivePrefix & "TOPICS " &_
		" WHERE " & strTablePrefix & "CATEGORY.CAT_ID = " & strActivePrefix & "TOPICS.CAT_ID " &_
		" AND " & strTablePrefix & "FORUM.FORUM_ID = " & strActivePrefix & "TOPICS.FORUM_ID " &_
		" AND " & strActivePrefix & "TOPICS.TOPIC_ID = " & strRqTopicID & ""
	else
		'## Forum_SQL - Find out if the Category or Forum is Locked or Un-Locked and if it Exists
		strSql = "SELECT " & strTablePrefix & "CATEGORY.CAT_STATUS, " &_
		strTablePrefix & "FORUM.F_STATUS " &_
		" FROM " & strTablePrefix & "CATEGORY, " &_
		strTablePrefix & "FORUM " &_
		" WHERE " & strTablePrefix & "CATEGORY.CAT_ID = " & strTablePrefix & "FORUM.CAT_ID " &_
		" AND " & strTablePrefix & "FORUM.FORUM_ID = " & strRqForumID & ""
        end if
 
	set rsStatus = my_Conn.Execute(strSql)
	if rsStatus.EOF or rsStatus.BOF then
		Go_Result "Please don't attempt to edit the URL<br>to gain access to locked Forums/Categories."
	else
		blnCStatus = rsStatus("CAT_STATUS")
		blnFStatus = rsStatus("F_STATUS")
		if strRqMethod <> "Topic" then
			blnTStatus = rsStatus("T_STATUS")
		else
			blnTStatus = 1
		end if
		rsStatus.close
		set rsStatus = nothing
	end if
 
	if (mLev = 4) or (chkForumModerator(strRqForumID, ChkString(strDBNTUserName, "decode"))= "1") or (lcase(strNoCookies) = "1") then
		AdminAllowed = 1
	else
		AdminAllowed = 0
	end if 
 
	select case strRqMethod
		case "Topic"
			if (blnCStatus = 0) and (AdminAllowed = 0) then
				Go_Result "You have attempted to post a New Topic to a Locked Category"
			end if
			if (blnFStatus = 0) and (AdminAllowed = 0) then
				Go_Result "You have attempted to post a New Topic to a Locked Forum"
			end if
		case "EditTopic"
			if ((blnCStatus = 0) or (blnFStatus = 0) or (blnTStatus = 0)) and (AdminAllowed = 0) then
				Go_Result "You have attempted to edit a Locked Topic"
			end if
		case "Reply", "ReplyQuote", "TopicQuote"
			if ((blnCStatus = 0) or (blnFStatus = 0) or (blnTStatus = 0)) and (AdminAllowed = 0) then
				Go_Result "You have attempted to Reply to a Locked Topic"
			end if
		case "Edit"
			if ((blnCStatus = 0) or (blnFStatus = 0) or (blnTStatus = 0)) and (AdminAllowed = 0) then
				Go_Result "You have attempted to Edit a Reply to a Locked Topic"
			end if
	end select
end if

select case strSelectSize
	case "1"
		intCols = 45
		intRows = 6
	case "2"
		intCols = 70
		intRows = 12
	case "3"
		intCols = 90
		intRows = 12
	case "4"
		intCols = 130
		intRows = 15
	case else
		intCols = 70
		intRows = 12
end select
%>
<SCRIPT LANGUAGE="JavaScript" SRC="selectbox.js"></SCRIPT>

<SCRIPT language="JavaScript">
<!--

function autoReload(objform)
{
	var tmpCookieURL = '<%=strCookieURL%>';
	if (objform.SelectSize.value == 1)
	{
		document.PostTopic.Message.cols = 45;
		document.PostTopic.Message.rows = 6;
	}
	if (objform.SelectSize.value == 2)
	{
		document.PostTopic.Message.cols = 70;
		document.PostTopic.Message.rows = 12;
	}
	if (objform.SelectSize.value == 3)
	{
		document.PostTopic.Message.cols = 90;
		document.PostTopic.Message.rows = 12;
	}
	if (objform.SelectSize.value == 4)
	{
		document.PostTopic.Message.cols = 130;
		document.PostTopic.Message.rows = 15;
	}
	document.cookie = tmpCookieURL + "strSelectSize=" + objform.SelectSize.value
}

function OpenPreview()
{
	var curCookie = "strMessagePreview=" + escape(document.PostTopic.Message.value);
	document.cookie = curCookie;
	popupWin = window.open('pop_preview.asp', 'preview_page', 'scrollbars=yes,width=750,height=450')	
}
//-->
</script>
<% 
if strRqMethod = "EditForum" then
	if (mLev = 4) or (chkForumModerator(strRqForumId, strDBNTUserName) = "1") then
		'## Do Nothing
	else
		Response.Write "<p>ERROR: Only moderators and administrators can edit forums</p>" & vbNewline
		WriteFooter
		Response.End
	end if
end if

Msg = ""

select case strRqMethod 
	case "Reply"
		if (strNoCookies = 1) or (strDBNTUserName = "") then
			Msg = Msg & "<b>Note:</b> You must be registered in order to post a reply.<br>"
			Msg = Msg & "To register, <a href=""policy.asp"">click here</a>. Registration is FREE!<br>"
		end if
	case "ReplyQuote"
		if (strNoCookies = 1) or (strDBNTUserName = "") then
			Msg = Msg & "<b>Note:</b> You must be registered in order to post a reply.<br>"
			Msg = Msg & "To register, <a href=""policy.asp"">click here</a>. Registration is FREE!<br>"
		end if
	case "Topic"
		if (strNoCookies = 1) or (strDBNTUserName = "") then
			Msg = Msg & "<b>Note:</b> You must be registered in order to post a Topic.<br>"
			Msg = Msg & "To register, <a href=""policy.asp"">click here</a>. Registration is FREE!<br>"
		end if
	case "TopicQuote"
		if (strNoCookies = 1) or (strDBNTUserName = "") then
			Msg = Msg & "<b>Note:</b> You must be registered in order to post a reply.<br>"
			Msg = Msg & "To register, <a href=""policy.asp"">click here</a>. Registration is FREE!<br>"
		end if
	case "Forum"
		Msg = Msg & "<b>Note:</b> You must be an administrator to create a new forum.<br>"
	case "URL"
		Msg = Msg & "<b>Note:</b> You must be an administrator to create a new web link.<br>"
	case "Edit"
		Msg = Msg & "<b>Note:</b> Only the poster of this message, and the Moderator can edit the message."
	case "EditTopic"
		Msg = Msg & "<b>Note:</b> Only the poster of this message, and the Moderator can edit the message."
	case "EditForum"
		Msg = Msg & "<b>Note:</b> Only the Moderator can edit the message."
	case "EditCategory"
		Msg = Msg & "Note: Only an administrator can edit the subject."
end select

if strRqMethod = "Edit" or _
strRqMethod = "ReplyQuote" then
	'## Forum_SQL
	strSql = "SELECT R_AUTHOR,R_MESSAGE "
	strSql = strSql & " FROM " & strActivePrefix & "REPLY "
	strSql = strSql & " WHERE " & strActivePrefix & "REPLY.REPLY_ID = " & Request.QueryString("REPLY_ID")

	set rs = my_Conn.Execute (strSql)
	
	strAuthor = rs("R_AUTHOR")

	if strRqMethod = "Edit" then
		TxtMsg = rs("R_MESSAGE")
	else
		if strRqMethod = "ReplyQuote" then
			TxtMsg = "[quote]" & vbNewline
			TxtMsg = TxtMsg & rs("R_MESSAGE") & vbNewline
			TxtMsg = TxtMsg & "[/quote]"
		end if
	end if
	'if strDBNTUserName = getMemberName(strAuthor) then 
		'boolReply =rs("R_MAIL") 
	'end if
end if

if strRqMethod = "EditTopic" or strRqMethod = "TopicQuote" then
	'## Forum_SQL
	strSql = "SELECT " & strActivePrefix & "TOPICS.CAT_ID, " &_
	strActivePrefix & "TOPICS.FORUM_ID, " &_
	strActivePrefix & "TOPICS.TOPIC_ID, " &_
	strActivePrefix & "TOPICS.T_SUBJECT, " &_
	strActivePrefix & "TOPICS.T_AUTHOR, " &_
	strActivePrefix & "TOPICS.T_MESSAGE " &_
	" FROM " & strActivePrefix & "TOPICS " &_
	" WHERE " & strActivePrefix & "TOPICS.TOPIC_ID = " & strRqTopicID

	set rs = my_Conn.Execute (strSql)

	TxtSub = rs("T_SUBJECT")
	strAuthor = rs("T_AUTHOR")

	if strRqMethod = "EditTopic" then
		TxtMsg = rs("T_MESSAGE")
	else
		if strRqMethod = "TopicQuote" then
			TxtMsg = "[quote]" & vbNewline
			TxtMsg = TxtMsg & rs("T_MESSAGE") & vbNewline
			TxtMsg = TxtMsg & "[/quote]"
		end if
	end if
	'if strDBNTUserName = getMemberName(strAuthor) then boolTopic = rs("T_MAIL")
end if

if strRqMethod = "EditForum" or _
strRqMethod = "EditURL" then
	'## Forum_SQL
	' DEM --> Added F_SUBSCRIPTION, F_MODERATION to the end of this select
	strSql = "SELECT " & strTablePrefix & "FORUM.F_SUBJECT, " & strTablePrefix & "FORUM.F_URL, " & _
			 strTablePrefix & "FORUM.F_DESCRIPTION, " & strTablePrefix & "FORUM.F_PRIVATEFORUMS, " & _
			 strTablePrefix & "FORUM.F_PASSWORD_NEW, " & strTablePrefix & "FORUM.F_SUBSCRIPTION, " & _
			 strTablePrefix & "FORUM.F_MODERATION " & _
			 " FROM " & strTablePrefix & "FORUM " & _
			 " WHERE " & strTablePrefix & "FORUM.FORUM_ID = " & strRqForumId

	set rs = my_Conn.Execute (strSql)
	
	if strRqMethod = "EditURL" then
		TxtUrl = rs("F_URL")
	end if

	if strRqMethod = "EditForum" or _ 
	strRqMethod = "EditURL" then
		TxtSub = rs("F_SUBJECT")
		TxtMsg = rs("F_DESCRIPTION")
		' DEM --> Added fields to get them into local variables which is a faster run
		ForumModeration   = rs("F_MODERATION")
		ForumSubscription = rs("F_SUBSCRIPTION")
	end if
end if

' DEM --> Added editforum and forum to get the cat_subscription and cat_moderation for later use.
if strRqMethod = "EditCategory" or strRqMethod = "EditForum" or strRqMethod = "Forum" then
	'## Forum_SQL
	strSql = "SELECT " & strTablePrefix & "CATEGORY.CAT_NAME "
	' DEM --> Added CAT_SUBSCRIPTION for subscription services
	strSql = strSql & ", " & strTablePrefix & "CATEGORY.CAT_SUBSCRIPTION "
	' DEM --> Added  CAT_MODERATION for moderation processing
	strSql = strSql & ", " & strTablePrefix & "CATEGORY.CAT_MODERATION "
	strSql = strSql & " FROM " & strTablePrefix & "CATEGORY "
	strSql = strSql & " WHERE " & strTablePrefix & "CATEGORY.CAT_ID = " & strRqCatID

	' DEM --> Added if statement to use a different connection and to move the database fields to local variables
	if strRqMethod = "EditForum" or strRqMethod = "Forum" then
		set rs1 = my_Conn.Execute (strSql)
		CatSubscription = rs1("CAT_SUBSCRIPTION")
		CatModeration   = rs1("CAT_MODERATION")
		set rs1 = nothing
	else
		set rs = my_Conn.Execute (strSql)
		CatSubscription = rs("CAT_SUBSCRIPTION")
		CatModeration   = rs("CAT_MODERATION")
	end if

	if strRqMethod = "EditCategory" then
		TxtSub = rs("CAT_NAME")
	end if
end if

select case strRqMethod 
	case "Category"
		btn = "Post New Category"
	case "Edit", "EditCategory", "EditForum", "EditTopic", "EditURL"
		btn = "Post Changes"
	case "Forum"
		btn = "Post New Forum"
	case "Reply", "ReplyQuote", "TopicQuote"
		btn = "Post New Reply"
	case "Topic"
		btn = "Post New Topic"
	case "URL"
		btn = "Post New URL"
	case else
		btn = "Post"
end select
%>
<table border="0" width="100%" align=center>
  <tr>
    <td width="33%" align="left"><font face="<% =strDefaultFontFace %>" size="<% =strDefaultFontSize %>">
    <img src="icon_folder_open.gif" border="0">&nbsp;<a href="default.asp">All Forums</a><br>
<%
if strRqMethod = "EditCategory" then
%>
    <img src="icon_bar.gif" border="0"><img src="icon_folder_open.gif" border="0">&nbsp;<% =ChkString(Request.QueryString("Cat_Title"),"display") %><br>
<% 
else 
	if strRqMethod = "Edit" or strRqMethod = "EditTopic" or _
		strRqMethod = "Reply" or strRqMethod = "ReplyQuote" or _
		strRqMethod = "Topic" or strRqMethod = "TopicQuote" then 
%>
    <img src="icon_bar.gif" border="0"><img src="icon_folder_open.gif" border="0">&nbsp;<a href="forum.asp?FORUM_ID=<% =strRqForumId %>"><% =ChkString(Request.QueryString("FORUM_Title"),"display") %></a><br>
<%
	end if 
 end if 

if strRqMethod = "Edit" or strRqMethod = "EditTopic" or _
	strRqMethod = "Reply" or strRqMethod = "ReplyQuote" or _
	strRqMethod = "TopicQuote" then 
%>
    <img src="icon_blank.gif" border="0"><img src="icon_bar.gif" border="0"><img src="icon_folder_open_topic.gif" border="0">&nbsp;<a href="topic.asp?TOPIC_ID=<% =strRqTopicID %>"><% =ChkString(Request.QueryString("Topic_Title"),"title") %></a>
<%
end if 
%>
    </font></td>
  </tr>
</table>

<p align="center"><font face="<% =strDefaultFontFace %>" size="<% =strDefaultFontSize %>">
<% =Msg %>
</font></p>
<table border="0" cellspacing="0" cellpadding="0" align=center>
  <tr>
    <td bgcolor="<% =strPopUpBorderColor %>">
    <table border="0" cellspacing="1" cellpadding="1">
<%
if strRqMethod = "Edit" or strRqMethod = "EditTopic" or strRqMethod = "EditForum" or _
	strRqMethod = "Reply" or strRqMethod = "ReplyQuote" or _
	strRqMethod = "Topic" or strRqMethod = "TopicQuote" then 
%>  
  	<form name="Screensize" method="POST" action="post.asp?method=<% =strRqMethod %>&FORUM_ID=<% =strRqForumId%>&CAT_ID=<% =strRqCatID%>&Forum_Title=<% =ChkString(Request.QueryString("FORUM_Title"),"urlpath")%>&TOPIC_ID=<% =ChkString(strRqTopicID,"urlpath")%>&REPLY_ID=<% =ChkString(Request.QueryString("REPLY_ID"),"urlpath")%>&Topic_Title=<% =ChkString(Request.QueryString("Topic_Title"),"urlpath")%>">
		<input name="ARCHIVE" type="hidden" value="<% = ArchiveView %>">
		<input name="Method_Type" type="hidden" value="<% =strRqMethod %>">
		<input name="Type" type="hidden" value="<% =Request.QueryString("type") %>">
		<input name="REPLY_ID" type="hidden" value="<% =Request.QueryString("REPLY_ID") %>">
		<input name="TOPIC_ID" type="hidden" value="<% =strRqTopicID %>">
		<input name="FORUM_ID" type="hidden" value="<% =strRqForumId %>"> 
		<input name="CAT_ID" type="hidden" value="<% =strRqCatID %>">
		<input name="Author" type="hidden" value="<% =strAuthor %>">
		<input name="Mod_ID" type="hidden" value="<% =Request.QueryString("mod") %>">
		<input name="Cat_Title" type="hidden" value="<% =ChkString(Request.QueryString("Cat_Title"), "hidden") %>">
		<input name="FORUM_Title" type="hidden" value="<% =ChkString(Request.QueryString("FORUM_Title"), "hidden") %>">
		<input name="Topic_Title" type="hidden" value="<% =ChkString(Request.QueryString("TOPIC_Title"), "hidden") %>">
		<input name="M" type="hidden" value="<% =Request.QueryString("M") %>">
		<input name="Refer" type="hidden" value="<% =Request.ServerVariables("HTTP_REFERER") %>">
		<input name="cookies" type="hidden" value="yes">
	<tr>
        <td bgColor="<% =strPopUpTableColor %>" noWrap vAlign="top" align="right"><font face="<% =strDefaultFontFace %>" size="<% =strDefaultFontSize %>"><b>Screensize:</b></font></td>
        <td bgColor="<% =strPopUpTableColor %>"><font face="<% =strDefaultFontFace %>" size="<% =strDefaultFontSize %>">
			<select name="SelectSize" size="1" onchange="autoReload(document.Screensize)">  
			<option value="1" <% if strSelectSize = "1" then Response.Write("SELECTED") %>>640  x 480</option>
			<option value="2" <% if strSelectSize = "2" or strSelectSize = "" then Response.Write("SELECTED") %>>800  x 600</option>			<option value="3" <% if strSelectSize = "3" then Response.Write("SELECTED") %>>1024 x 768</option>
			<option value="4" <% if strSelectSize = "4" then Response.Write("SELECTED") %>>1280 x 1024</option>      
			</select></font>
		</td>
	</tr>
	</form>
<%
end if 
%>
<form action="post_info.asp" method="post" name="PostTopic">
<input name="ARCHIVE" type="hidden" value="<% = ArchiveView %>">
<input name="Method_Type" type="hidden" value="<% =strRqMethod %>">
<input name="Type" type="hidden" value="<% =Request.QueryString("type") %>">
<input name="REPLY_ID" type="hidden" value="<% =Request.QueryString("REPLY_ID") %>">
<input name="TOPIC_ID" type="hidden" value="<% =strRqTopicID %>">
<input name="FORUM_ID" type="hidden" value="<% =strRqForumId %>"> 
<input name="CAT_ID" type="hidden" value="<% =strRqCatID %>">
<input name="Author" type="hidden" value="<% =strAuthor %>">
<input name="Mod_ID" type="hidden" value="<% =Request.QueryString("mod") %>">
<input name="Cat_Title" type="hidden" value="<% =ChkString(Request.QueryString("Cat_Title"), "hidden") %>">
<input name="FORUM_Title" type="hidden" value="<% =ChkString(Request.QueryString("FORUM_Title"), "hidden") %>">
<input name="Topic_Title" type="hidden" value="<% =ChkString(Request.QueryString("TOPIC_Title"), "hidden") %>">
<input name="M" type="hidden" value="<% =Request.QueryString("M") %>">
<input name="Refer" type="hidden" value="<% =Request.ServerVariables("HTTP_REFERER") %>">
<input name="cookies" type="hidden" value="yes">
<% 
if mlev = 4 or _
mlev = 3 or _
mlev = 2 or _
mlev = 1 then 
%>
    <input name="UserName" type="hidden" Value="<% =strDBNTUserName%>">
    <input name="Password" type="hidden" value="<% =strCkPassWord%>">
<%
else
	if (lcase(strNoCookies) = "1") or _
	(strDBNTUserName = "" or _
	strCkPassWord = "") then 
%>
      <tr>
        <td bgColor="<% =strPopUpTableColor %>" noWrap vAlign="top" align="right"><font face="<% =strDefaultFontFace %>" size="<% =strDefaultFontSize %>"><b>UserName:</b></font></td>
        <td bgColor="<% =strPopUpTableColor %>"><input name="UserName" maxLength="25" size="25" type="text" value="<%=Request.Form("UserName")%>"></td>
      </tr>
      <tr>
        <td bgColor="<% =strPopUpTableColor %>" noWrap vAlign="top" align="right"><font face="<% =strDefaultFontFace %>" size="<% =strDefaultFontSize %>"><b>Password:</b></font></td>
        <td bgColor="<% =strPopUpTableColor %>" valign="top"><input name="Password" maxLength="13" size="13" type="password" value="<%=Request.Form("password")%>"></td>
      </tr>
<%
	end if 
end if

if strAllowForumCode = "1" then
	if strRqMethod = "Edit" or strRqMethod = "EditTopic" or _
		strRqMethod = "Reply" or strRqMethod = "ReplyQuote" or _
		strRqMethod = "Topic" or strRqMethod = "TopicQuote" then 
%>
<!--#INCLUDE FILE="inc_post_buttons.asp" -->
<% 
	end if
end if
if strRqMethod = "Forum" or _
strRqMethod = "URL" or _
strRqMethod = "EditURL" or _
strRqMethod = "EditForum" then 
%>
      <tr>
        <td bgColor="<% =strPopUpTableColor %>" noWrap vAlign="top" align="right"><font face="<% =strDefaultFontFace %>" size="<% =strDefaultFontSize %>"><b>Category:</b></font></td>
        <td bgColor="<% =strPopUpTableColor %>">
        <select name="Category" size="1">
<%
'## Forum_SQL
strSql = "SELECT " & strTablePrefix & "CATEGORY.CAT_ID, " & strTablePrefix & "CATEGORY.CAT_NAME "
strSql = strSql & " FROM " & strTablePrefix & "CATEGORY "
if mlev = 3 then 
	strSql = strSql & " WHERE CAT_ID = " & strRqCatID
end if 
strSql = strSql & " ORDER BY " & strTablePrefix & "CATEGORY.CAT_NAME ASC;"

set rsCat = my_Conn.execute (strSql)

'On Error Resume Next
do until rsCat.eof
	Response.Write "          <option value=""" & rsCat("CAT_ID") & """"
	if cint(strRqCatID) = rsCat("CAT_ID") then
		Response.Write " selected"
	end if
	Response.Write ">" & ChkString(rsCat("CAT_NAME"),"display") & "</option>" & vbNewline
	rsCat.movenext
loop
set rsCat = nothing
%>
        </select>
        </td>
      </tr>
<%
end if

if (strRqMethod = "EditTopic") then
%>
      <tr>
        <td bgColor="<% =strPopUpTableColor %>" noWrap vAlign="top" align="right"><font face="<% =strDefaultFontFace %>" size="<% =strDefaultFontSize %>"><b>Forum:</b></font></td>
        <td bgColor="<% =strPopUpTableColor %>">
<%
	if mlev = 3 or _
	mlev = 4 then 
%>
        <select name="Forum" size="1">
<%
	end if 
	'## Forum_SQL
	strSql = "SELECT " & strTablePrefix & "FORUM.CAT_ID, " &_
	strTablePrefix & "FORUM.FORUM_ID, " &_
	strTablePrefix & "FORUM.F_SUBJECT, " &_
	strTablePrefix & "FORUM.F_TYPE " &_
	" FROM " & strTablePrefix & "FORUM " &_
	" WHERE F_TYPE = 0 "
	if mLev = 4 then
		'## Do Nothing
	else
		if mLev = 3 and _
			strMoveTopicMode = "1" then
		else
			if (mLev < 3) then
				strSql = strSql & " AND   FORUM_ID = " & rs("FORUM_ID")
			end if
		end if
	end if
	strSql = strSql & " ORDER BY " & strTablePrefix & "FORUM.F_SUBJECT ASC;"

	set rsForum = my_Conn.execute (strSql)

	if mlev = 3 or _
	mlev = 4 then
		on error resume next
		do until rsForum.eof
			Response.Write "          <option value='" & rsForum("CAT_ID") & "|" & rsForum("FORUM_ID") & "'"
			if cint(strRqForumId) = rsForum("FORUM_ID") then
				Response.Write " selected"
			end if
			Response.Write ">" & ChkString(rsForum("F_SUBJECT"),"display") & "</option>" & vbNewline
			rsForum.movenext
		loop
	else
		Response.Write "          <font face='" & strDefaultFontFace & "' size=" & strDefaultFontSize & ">" & ChkString(rsForum("F_SUBJECT"),"display") & "</font>"
		Response.Write "<input type='hidden' name='Forum' value='" & rsForum("CAT_ID") & "|" & rsForum("FORUM_ID") & "'>"
	end if
		
	set rsForum = nothing

	if mlev = 3 or _
	mlev = 4 then 
        Response.Write "</select>" & vbNewline
	end if
end if 

if strRqMethod = "Category" or _
strRqMethod = "EditCategory" or _
strRqMethod = "URL" or _
strRqMethod = "EditURL" or _
strRqMethod = "Forum" or _
strRqMethod = "EditForum" or _
strRqMethod = "EditTopic" or _
strRqMethod = "Topic" then
%>
      <tr>
        <td bgColor="<% =strPopUpTableColor %>" noWrap vAlign="top" align="right"><font face="<% =strDefaultFontFace %>" size="<% =strDefaultFontSize %>"><b>Subject:</b></font></td>
        <td bgColor="<% =strPopUpTableColor %>"><input maxLength="50" name="Subject" value="<% =Trim(ChkString(TxtSub,"edit")) %>" size="40"></td>
      </tr>
<%
end if

if strRqMethod = "URL" or _
strRqMethod = "EditURL" then 
%>
      <tr>
        <td bgColor="<% =strPopUpTableColor %>" noWrap vAlign="top" align="right"><font face="<% =strDefaultFontFace %>" size="<% =strDefaultFontSize %>"><b>Address:</b></font></td>
        <td bgColor="<% =strPopUpTableColor %>"><input maxLength="150" name="Address" value="<% if (TxtURL <> "") then Response.Write(TxtURL) else Response.Write("http://") %>" size="40"></td>
      </tr>
<%
end if
 
if strRqMethod = "Edit" or strRqMethod = "URL" or strRqMethod = "EditURL" or _
	strRqMethod = "Forum" or strRqMethod = "EditForum" or _
	strRqMethod = "Reply" or strRqMethod = "ReplyQuote" or _
	strRqMethod = "EditTopic" or strRqMethod = "Topic" or strRqMethod = "TopicQuote" then 
%>
      <tr>
        <td bgColor="<% =strPopUpTableColor %>" noWrap vAlign="top" align="right"><font face="<% =strDefaultFontFace %>" size="<% =strDefaultFontSize %>"><b>Message:</b><br>
        <br>
        <table border=0>
          <tr>
            <td align="left" nowrap><font face="<% =strDefaultFontFace %>" size="<% =strDefaultFontSize %>">
<% if strAllowHTML = "1" then %>
            * HTML is ON<br>
<% else %>
            * HTML is OFF<br>
<% end if %>
<% if strAllowForumCode = "1" then %>
            * <a href="JavaScript:openWindow3('pop_forum_code.asp')">Forum Code</a> is ON<br>
<% else %>
            * Forum Code is OFF<br>
<% end if %>
            </font>  
            </td>
          </tr>
        </table>
        </font>    
        </td>
        <td bgColor="<% =strPopUpTableColor %>"><textarea cols="<%=intCols %>" name="Message" rows="<%=intRows %>" wrap="VIRTUAL"><% =Trim(CleanCode(TxtMsg))%></textarea><br>
        </td>
      </tr>
<% 
end if

' DEM --> Start of Code added for full moderation and subscription services
if strRqMethod = "Forum" or strRqMethod = "EditForum" or _
   strRqMethod = "Category" or strRqMethod = "EditCategory" then
	if strSubscription > 0 and _ 
      ((strRqMethod = "Category" or strRqMethod = "EditCategory") or _
       ((strRqMethod = "Forum"   or strRqMethod = "EditForum") and (CatSubscription > 0))) then
		' Subscription service first.....
		Response.Write "        <tr>" & vbNewline
		Response.Write "        <td bgColor='" & strPopUpTableColor & "' noWrap vAlign='top' align='right'>"
		Response.Write "<font face='" & strDefaultFontFace & "' size='" & strDefaultFontSize & "'><b>Subscription:</b></font></td>"
		Response.Write "        <td bgColor='" & strPopUpTableColor & "' noWrap vAlign='top'>"
		Response.Write "<font face='" & strDefaultFontFace & "' size='" & strDefaultFontSize & "'>"
		Response.Write "        <select name='Subscription'>"
		if strRqMethod = "Category" or strRqMethod = "EditCategory" then
			Response.Write "          <option"
			if CatSubscription = 0 then
				Response.Write " selected "
			end if
			Response.Write " value='0'>No Subscriptions Allowed</option>"
			' If Whole Board or Category Level Subscriptions Allowed, show option
			if strSubscription < 3 then
				Response.Write "          <option"
			    if CatSubscription = 1 then
					Response.Write " selected "
				end if
				Response.Write " value='1'>Category Subscriptions Allowed</option>"
			end if
			' If Whole Board, Category Level or Forum Level Subscriptions Allowed, show option
			if strSubscription < 4 then
				Response.Write "          <option"
			    if CatSubscription = 2 then
					Response.Write " selected "
				end if
				Response.Write " value='2'>Forum Subscriptions Allowed</option>"
			end if
			Response.Write "          <option"
		    if CatSubscription = 3 then
				Response.Write " selected "
			end if
			Response.Write " value='3'>Topic Subscriptions Allowed</option>"
		else
			Response.Write "          <option"
	    	if ForumSubscription = 0 then
				Response.Write " selected "
			end if
			Response.Write " value='0'>No Subscriptions Allowed</option>"
			' If Whole Board, Category Level or Forum Level Subscriptions Allowed, show option
			if strSubscriptions < 4 and CatSubscription < 3 then
				Response.Write "          <option"
			    if ForumSubscription = 1 then
					Response.Write " selected "
				end if
				Response.Write " value='1'>Forum Subscriptions Allowed</option>"
			end if
			Response.Write "          <option"
		    if ForumSubscription = 2 then
				Response.Write " selected "
			end if
			Response.Write " value='2'>Topic Subscriptions Allowed</option>"
		end if
		Response.Write "</select>" & vbNewline
		Response.Write "</font>" & vbNewline
		Response.Write "</td>" & vbNewline
	end if
   
   ' Topic Moderation Code - Check if Moderation is allowed over the entire board, then
   ' check if Moderation is allowed for the next level up.
   	if strModeration > 0 and _
      ((strRqMethod = "Category" or strRqMethod = "EditCategory") or _
       ((strRqMethod = "Forum"   or strRqMethod = "EditForum") and CatModeration > 0)) then
   		Response.Write "        <tr>" & vbNewline
	   	Response.Write "        <td bgColor='" & strPopUpTableColor & "' noWrap vAlign='top' align='right'>"
		Response.Write "<font face='" & strDefaultFontFace & "' size='" & strDefaultFontSize & "'><b>Moderation:</b></font></td>"
		Response.Write "        <td bgColor='" & strPopUpTableColor & "' noWrap vAlign='top'>"
		Response.Write "<font face='" & strDefaultFontFace & "' size='" & strDefaultFontSize & "'>"
		Response.Write "        <select name='Moderation'>"
		if strRqMethod = "Category" or strRqMethod = "EditCategory" then
			Response.Write "          <option"
			if CatModeration = 0 then
				Response.Write " selected "
			end if
			Response.Write " value='0'>Moderation Not Allowed in this Category</option>"
			Response.Write "          <option"
			if CatModeration = 1 then
				Response.Write " selected "
			end if
			Response.Write " value='1'>Moderation Allowed in this Category</option>"
   		else  	  
			Response.Write "          <option"
      		if ForumModeration = 0 then
	     		Response.Write " selected "
	  		end if
	  		Response.Write " value='0'>No Moderation for this forum</option>"
			Response.Write "          <option"
      		if ForumModeration = 1 then
	     		Response.Write " selected "
	  		end if
	  		Response.Write " value='1'>All Posts Moderated</option>"
			Response.Write "          <option"
      		if ForumModeration = 2 then
	     		Response.Write " selected "
	  		end if
	  		Response.Write " value='2'>Original Posts Only Moderated</option>"
			Response.Write "          <option"
      		if ForumModeration = 3 then
	     		Response.Write " selected "
	  		end if
	  		Response.Write " value='3'>Replies Only Moderated</option>"
   		end if
   		Response.Write "</select>" & vbNewline
   		Response.Write "</font>" & vbNewline
   		Response.Write "</td>" & vbNewline
	end if
end if
' DEM --> End of Code Added for Moderation and Subscription
 
if strRqMethod = "Edit" or _
	strRqMethod = "URL" or strRqMethod = "EditURL" or _
	strRqMethod = "Reply" or strRqMethod = "ReplyQuote" or _
	strRqMethod = "EditTopic" or strRqMethod = "Topic" or strRqMethod = "TopicQuote" then 
%>
      <tr>
        <td bgColor="<% =strPopUpTableColor %>">&nbsp;</td>
        <td bgColor="<% =strPopUpTableColor %>">
<% 
	if strAllowForumCode = "1" then
		if strRqMethod = "Edit" or strRqMethod = "EditTopic" or strRqMethod = "Reply" or _
			strRqMethod = "ReplyQuote" or strRqMethod = "Topic" or strRqMethod = "TopicQuote" then 
%>
        <table border=0>
         <tr>
          <td>
          <font face="<% =strDefaultFontFace %>" size="<% =strDefaultFontSize %>"><b>Mode:</b>
		      <select name="font" onChange="thelp(this.options[this.selectedIndex].value)">
				<option value="1">Help&nbsp;</option>
				<option value="2">Prompt&nbsp;</option>
				<option selected value="0">Basic&nbsp;</option>
	  		  </select>          
			</font></td>
          </tr>
        </table>
<%
		end if
	end if

	if strRqMethod = "Edit" or strRqMethod = "Reply" or strRqMethod = "ReplyQuote" or _
		strRqMethod = "Topic" or strRqMethod = "EditTopic" or strRqMethod = "TopicQuote" then 
		if strRqMethod = "Reply" or strRqMethod = "ReplyQuote" or _
			strRqMethod = "Topic" or strRqMethod = "TopicQuote" then 
%>
        <font face="<% =strDefaultFontFace %>" size="<% =strDefaultFontSize %>">
        <input name="Sig" type="checkbox" value="yes" checked>Check here to include your profile signature.<br>
        </font>
<%
		end if 

		if 	((mLev = 4) or (chkForumModerator(strRqForumId, strDBNTUserName) = "1")) _
		and (strRqMethod = "Topic" or strRqMethod = "Reply" or _
		strRqMethod = "ReplyQuote" or strRqMethod = "TopicQuote") then %>
        <font face="<% =strDefaultFontFace %>" size="<% =strDefaultFontSize %>">
        <input name="lock" type="checkbox" value="1">Check here to lock the topic after this post.<br>
        </font>
<%
		end if
	end if
	Response.Write "        </td>" & vbNewline
	Response.Write "      </tr>" & vbNewline
end if 
%>
<% 
if strPrivateForums <> "0" then 
	if strRqMethod = "Forum" or _
	strRqMethod = "URL" or _
	strRqMethod = "EditURL" or _
	strRqMethod = "EditForum" then 
		if strRqMethod = "EditForum" or _
		strRqMethod = "EditURL" then
			ForumAuthType = rs("F_PRIVATEFORUMS")
		else
			ForumAuthType = 0
		end if
%>
      <tr>
        <td bgColor="<% =strPopUpTableColor %>" noWrap vAlign="top" align="right"><font face="<% =strDefaultFontFace %>" size="<% =strDefaultFontSize %>"><b>Auth Type:</b></font></td>
        <td bgColor="<% =strPopUpTableColor %>"><SELECT readonly name="AuthType">
        <option value="0" <% if ForumAuthType = 0 then Response.Write(" selected") %>>All Visitors</option>
        <option value="4" <% if ForumAuthType = 4 then Response.Write(" selected") %>>Members Only</option>
        <option value="5" <% if ForumAuthType = 5 then Response.Write(" selected") %>>Members Only (Hidden)</option>
<%
		if strRqMethod = "Forum" or _
		strRqMethod = "EditForum" then 
%>
        <option value="2" <% if ForumAuthType = 2 then Response.Write(" selected") %>>Password Protected</option>
        <option value="7" <% if ForumAuthType = 7 then Response.Write(" selected") %>>Members Only & Password Protected</option>
        <option value="3" <% if ForumAuthType = 3 then Response.Write(" selected") %>>Allowed Member List & Password Protected</option>
<%		end if %>
        <option value="1" <% if ForumAuthType = 1 then Response.Write(" selected") %>>Allowed Member List</option>
        <option value="6" <% if ForumAuthType = 6 then Response.Write(" selected") %>>Allowed Member List (Hidden)</option>
<%		if strNTGroups = "1" then %>
        <option value="9" <% if ForumAuthType = 9 then Response.Write(" selected") %>>NT Global Group</option>
        <option value="8" <% if ForumAuthType = 8 then Response.Write(" selected") %>>NT Global Group (Hidden)</option>
<%		end if %>
        </select>
<%
		if strRqMethod = "Forum" or _
		strRqMethod = "EditForum" then 
			if strRqMethod = "EditForum" then 
				If rs("F_PASSWORD_NEW") <> " " Then
					strPassword = ChkString(rs("F_PASSWORD_NEW"),"password")
				else 
					strPassword = " "
				end if
			else
				strPassword = " "
			end if
%>
        <br><font face="<% =strDefaultFontFace %>" size="<% =strDefaultFontSize %>"><b>Password <% if strNTGroups = "1" then Response.Write("or Global Groups") %>:</b><br></font> 
        <input maxLength="255" type="text" name="AuthPassword" size="60" value="<%=strPassword%>">
<%		end if %>
        </td>
      </tr>
      <tr>
        <td bgColor="<% =strPopUpTableColor %>" noWrap vAlign="top" align="right"><font face="<% =strDefaultFontFace %>" size="<% =strDefaultFontSize %>"><b>Member List:</b></font></td>
<%
		'#################################################################################
		'## Allowed User - listbox Code
		'#################################################################################
		strSql = "SELECT " & strMemberTablePrefix & "MEMBERS.MEMBER_ID, " & strMemberTablePrefix & "MEMBERS.M_NAME "
		strSql = strSql & " FROM " & strMemberTablePrefix & "MEMBERS "
		strSql = strSql & " ORDER BY " & strMemberTablePrefix & "MEMBERS.M_NAME ASC;"
		
		on error resume next
		
		set rsMember = my_Conn.execute (strSql)

		strSql = "SELECT " & strTablePrefix & "ALLOWED_MEMBERS.MEMBER_ID "
		strSql = strSql & " FROM " & strTablePrefix & "ALLOWED_MEMBERS "
		strSql = strSql & " WHERE " & strTablePrefix & "ALLOWED_MEMBERS.FORUM_ID = " & strRqForumID

		set rsAllowedMember = my_Conn.execute (strSql)

		tmpStrUserList  = ""
		if strRqMethod = "EditForum" or strRqMethod = "EditURL" then
			do while not (rsAllowedMember.EOF or rsAllowedMember.BOF)
				if tmpStrUserList = "" then
					tmpStrUserList = rsAllowedMember("MEMBER_ID")
				else
					tmpStrUserList = tmpStrUserList & "," & rsAllowedMember("MEMBER_ID")
				end if
				rsAllowedMember.movenext
			loop
		end if
		SelectSize = 10
%>                   
        <td bgColor="<% =strPopUpTableColor %>">
        <table>
          <tr>
		    <td>
		    <font face="<% =strDefaultFontFace %>" size="<% =strDefaultFontSize %>"><b>Forum Members:</b></font><br>
		    <select name="AuthUsersCombo" size="<%=SelectSize %>" multiple onDblClick="moveSelectedOptions(document.PostTopic.AuthUsersCombo, document.PostTopic.AuthUsers, false, '')">
<%
		'## Pick from list
		rsMember.movefirst
		do until rsMember.eof
			if not(Instr("," & tmpStrUserList & "," , "," & rsMember("MEMBER_ID") & ",",1) > 0) then
				Response.Write "		    <option value=""" & rsMember("MEMBER_ID") & """" & isSel & ">" & ChkString(rsMember("M_NAME"),"display") & "</option>" & vbNewline
			end if
			rsMember.movenext
		loop
		if tmpStrUserList <> "" then
%>      
		    <option value="<% =tmpStrUserList %>"></option>
<%		end if  %>
		    </select>
		    </td>
		    <td width="15" align="center" valign="middle">
	  	    <a href="javascript:moveAllOptions(document.PostTopic.AuthUsers, document.PostTopic.AuthUsersCombo, false, '')"><img src="icon_Private_remall.gif" width="23" height="22" border="0" alt=""></a>
		    <a href="javascript:moveSelectedOptions(document.PostTopic.AuthUsers, document.PostTopic.AuthUsersCombo, false, '')"><img src="icon_Private_remove.gif" width="23" height="22" border="0" alt=""></a>
		    <a href="javascript:moveSelectedOptions(document.PostTopic.AuthUsersCombo, document.PostTopic.AuthUsers, false, '')"><img src="icon_Private_add.gif" width="23" height="22" border="0" alt=""></a>
		    <a href="javascript:moveAllOptions(document.PostTopic.AuthUsersCombo, document.PostTopic.AuthUsers, false, '')"><img src="icon_Private_addall.gif" width="23" height="22" border="0" alt=""></a>
		    </td>
		    <td>
		    <font face="<% =strDefaultFontFace %>" size="<% =strDefaultFontSize %>"><b>Select Members:</b></font><br>
		    <select name="AuthUsers" size="<%=SelectSize %>" multiple onDblClick="moveSelectedOptions(document.PostTopic.AuthUsers, document.PostTopic.AuthUsersCombo, false, '')">
<%
		'## Selected List
		rsAllowedMember.movefirst
		if strRqMethod = "EditForum" or strRqMethod = "EditURL" then	
			do until rsAllowedMember.EOF
				if rsAllowedMember("MEMBER_ID") <> "" then
					Response.Write "		    <option value=""" & rsAllowedMember("MEMBER_ID") & """>" & ChkString(getMemberName(rsAllowedMember("MEMBER_ID")),"display") & "</option>" & vbNewline
				end if
				rsAllowedMember.movenext
			loop
		end if
		set rsAllowedMember = nothing
		if tmpStrUserList <> "" then
%>
		    <option value="<% =tmpStrUserList %>"></option>
<%
		end if 
%>
		    </select>
		    </td>
		  </tr>
		</table>
        </td>
      </tr>
<%
		'#################################################################################
		'## Allowed User - End of listbox code
		'#################################################################################
	end if
end if 

Response.Write	"      <tr>" & vbNewline & _
				"        <td bgColor=""" & strPopUpTableColor & """>&nbsp;</td>" & vbNewline & _
				"        <td bgColor=""" & strPopUpTableColor & """><input name=""Submit"" type=""submit"" value=""" & btn & """"
if strPrivateForums <> "0" then 
	if strRqMethod = "Forum" or _
	strRqMethod = "URL" or _
	strRqMethod = "EditURL" or _
	strRqMethod = "EditForum" then 
		Response.Write	" onclick=""selectUsers()"""
	end if
end if
Response.Write	">"

if strAllowForumCode = "1" or strAllowHTML = "1" then
if strRqMethod = "Reply" or _
	strRqMethod = "ReplyQuote" or _
	strRqMethod = "Edit" or _
	strRqMethod = "EditTopic" or _
	strRqMethod = "Topic" or _
	strRqMethod = "TopicQuote" then 
		Response.Write	"        &nbsp;<input name=""Preview"" type=""button"" value="" Preview "" onclick=""OpenPreview()"">"
	end if 
end if
Response.Write	"        &nbsp;<input name=""Reset"" type=""reset"" value=""Reset Fields""></td>" & vbNewline & _
				"      </tr>" & vbNewline & _
				"    </table>" & vbNewline & _
				"    </td>" & vbNewline & _
				"  </tr>" & vbNewline & _
				"</table>" & vbNewline & _
				"</form>"

if strRqMethod = "Reply" or _
	strRqMethod = "TopicQuote" or _
	strRqMethod = "ReplyQuote" then
%>
</table>
<table border="0" width="100%" align=center>
<table border="0" width="100%" cellspacing="0" cellpadding="0" align="center">
  <tr>
    <td bgcolor="<% =strTableBorderColor %>">
    <table border="0" width="100%" cellspacing="1" cellpadding="4">
      <tr>
        <td bgcolor="<% =strHeadCellColor %>" colspan="2" align="center"><b><font <% =strDefaultFontFace %> size="<% =strDefaultFontSize %>" color="<% =strHeadFontColor %>">T O P I C  &nbsp;&nbsp;&nbsp; R E V I E W</font></b></td>
      </tr>
<%
	' DEM --> Added Select of Moderation Fields
	strSQL = "SELECT " & strTablePrefix & "CATEGORY.CAT_MODERATION, "
	strSQL = strSQL & strTablePrefix & "FORUM.F_MODERATION "
	strSQL = strSQL & "FROM " & strTablePrefix & "CATEGORY, " & strTablePrefix & "FORUM "
	strSQL = strSQL & " WHERE " & strTablePrefix & "CATEGORY.CAT_ID = " & strRqCatID
	strSQL = strSQL & " AND " & strTablePrefix & "FORUM.FORUM_ID = " & strRqForumID
	set rsa = my_Conn.Execute (strSql) 
	' ## Moderators and Admins can see unmoderated posts.
	if (mLev = 4) or (chkForumModerator(strRqForumId, strDBNTUserName) = "1") then
		Moderation = "N"
	else
		if strModeration = 1 and rsa("CAT_MODERATION") = 1 and (rsa("F_MODERATION") = 1 or rsa("F_MODERATION") = 3) then
			Moderation = "Y"
		else
			Moderation = "N"
		end if
	end if
	' DEM --> End of Moderation Code

	'## Forum_SQL
	strSql = "SELECT " & strMemberTablePrefix & "MEMBERS.M_NAME, " & strActivePrefix & "TOPICS.T_MESSAGE " 
	strSql = strSql & " FROM " & strMemberTablePrefix & "MEMBERS, " & strActivePrefix & "TOPICS "
	strSql = strSql & " WHERE " & strMemberTablePrefix & "MEMBERS.MEMBER_ID = " & strActivePrefix & "TOPICS.T_AUTHOR AND "
	strSql = strSql & "       " & strActivePrefix & "TOPICS.TOPIC_ID = " &  strRqTopicID

	set rs = my_Conn.Execute (strSql) 

	Response.Write "      <tr>" & vbNewline
	Response.Write "        <td bgcolor='" & strForumFirstCellColor & "' valign=top width='" & strTopicWidthLeft & "'"
	if lcase(strTopicNoWrapLeft) = "1" then
		Response.Write " nowrap"
	end if 
	Response.Write "><font color='" & strForumFontColor & "' face='" & strDefaultFontFace & "' size='2'><b>" & ChkString(rs("M_NAME"),"display") & "</b></font></td>" & vbNewline
	Response.Write "        <td bgcolor='" & strForumCellColor & "' valign='top' width='" & strTopicWidthRight & "'" 
	if lcase(strTopicNoWrapRight) = "1" then
		Response.Write " nowrap"
	end if 
	Response.Write "><font color='" & strForumFontColor & "' face='" & strDefaultFontFace & "' size='2'>" & formatStr(rs("T_MESSAGE")) & "</font></td>" & vbNewline
	Response.Write "      </tr>" & vbNewline

	'## Forum_SQL - Get all replies to Topic from the DB
	strSql ="SELECT " & strMemberTablePrefix & "MEMBERS.M_NAME, " & strActivePrefix & "REPLY.R_MESSAGE "
	strSql = strSql & " FROM " & strMemberTablePrefix & "MEMBERS, " & strActivePrefix & "REPLY "
	strSql = strSql & " WHERE " & strMemberTablePrefix & "MEMBERS.MEMBER_ID = " & strActivePrefix & "REPLY.R_AUTHOR "
	strSql = strSql & " AND   TOPIC_ID = " & strRqTopicID & " "
	' DEM --> Added check for moderation so that only admins and moderators can see the unapproved posts.
	if Moderation = "Y" then
		strSql = strSql & " AND R_STATUS < 2 "		' Ignore unapproved and rejected posts...
	else
		strSql = strSql & " AND R_STATUS < 3 "		' Ignore all rejected posts....
	end if
	strSql = strSql & " ORDER BY " & strActivePrefix & "REPLY.R_DATE"

	set rs = Server.CreateObject("ADODB.Recordset")

'	rs.cachesize=15
	rs.open  strSql, my_Conn, 3

	strI = 0 
	if rs.EOF or rs.BOF then
		Response.Write ""
	else
		rs.movefirst
		do until rs.EOF
			if strI = 0 then
	 			CColor = strAltForumCellColor
			else
				CColor = strForumCellColor
			end if
			Response.Write "      <TR>" & vbNewline & _
						   "        <TD bgcolor='" & CColor & "' valign='top'" & vbNewline
			if lcase(strTopicNoWrapLeft) = "1" then
				Response.Write " nowrap"
			end if 
			Response.Write "><b><font color='" & strForumFontColor & "' face='" & strDefaultFontFace & "' size='2'>" &  ChkString(rs("M_NAME"),"display") & "</font></b></td>" & vbNewline & _
						   "        <TD bgcolor='" & CColor & "' valign='top'"
			if lcase(strTopicNoWrapRight) = "1" then
				Response.Write " nowrap"
			end if
			Response.Write "><font color='" & strForumFontColor & "' face='" & strDefaultFontFace & "' size='2'>" & formatStr(rs("R_MESSAGE")) & "</font></td>" & vbNewline & _
						   "      </tr>" & vbNewline
			rs.MoveNext
			strI = strI + 1
			if strI = 2 then 
				strI = 0
			end if
		loop
	end if

	Response.Write	"    </table>" & vbNewline  & _
					"    </td>" & vbNewline & _
					"  </tr>" & vbNewline  & _
					"</table>" & vbNewline & _
					"</font>" & vbNewline  
end if
WriteFooter

 function Go_Result(message) 
	Response.write 	"<br><div align=""center"">" & message & "</div>" &_
					"<br>" &_
					"<meta http-equiv=""Refresh"" content=""2; URL=default.asp"">"
	WriteFooter
	Response.end
end function
%>